flake.nix

{
    description = "flake for TechNet";

    inputs = {
        nixpkgs = {
            url = "github:NixOS/nixpkgs/nixos-unstable";
        };
        nix-index-database = {
            url = "github:nix-community/nix-index-database";
            inputs.nixpkgs.follows = "nixpkgs";
        };
        mobile-nixos = {
            url = "github:NixOS/mobile-nixos";
            flake = false;
        };
        sops-nix = {
            url = "github:Mic92/sops-nix";
            inputs.nixpkgs.follows = "nixpkgs";
        };
        disko = {
            url = "github:nix-community/disko";
            inputs.nixpkgs.follows = "nixpkgs";
        };
        impermanence = {
            url = "github:nix-community/impermanence";
            inputs.nixpkgs.follows = "nixpkgs";
        };
        arion = {
            url = "github:hercules-ci/arion";
            inputs.nixpkgs.follows = "nixpkgs";
        };
        blockurl = {
            url = "github:BeatLink/BlockURL?dir=sync-server";
            inputs.nixpkgs.follows = "nixpkgs";
        };
        home-manager = {
            url = "github:nix-community/home-manager";
            inputs.nixpkgs.follows = "nixpkgs";
        };
        xdg-autostart = {
            url = "github:Zocker1999NET/home-manager-xdg-autostart";
            inputs.nixpkgs.follows = "nixpkgs";
        };
        gmusicbrowser = {
            url = "github:BeatLink/gmusicbrowser-nix-flake";
            inputs.nixpkgs.follows = "nixpkgs";
        };
        halon = {
            url = "github:BeatLink/Halon";
            inputs.nixpkgs.follows = "nixpkgs";
        };
        claude-chat-manager = {
            url = "github:BeatLink/claude-chat-manager";
            inputs.nixpkgs.follows = "nixpkgs";
        };
        anthem = {
            url = "github:BeatLink/Anthem";
            inputs.nixpkgs.follows = "nixpkgs";
        };
        playitslowly = {
            url = "github:BeatLink/playitslowly";
            inputs.nixpkgs.follows = "nixpkgs";
        };
        # Patches the Steam client so it loads CSS themes; Odin's Steam package comes from here
        millennium = {
            url = "github:SteamClientHomebrew/Millennium?dir=packages/nix";
            inputs.nixpkgs.follows = "nixpkgs";
        };
        # git+ and submodules=1, not github:, because the stock themes are a submodule and a tarball fetch drops them
        web-greeter = {
            url = "git+https://github.com/BeatLink/web-greeter?ref=nix-flake&submodules=1";
            inputs.nixpkgs.follows = "nixpkgs";
        };
        linux-sidebar = {
            url = "github:BeatLink/linux-sidebar";
            inputs.nixpkgs.follows = "nixpkgs";
        };
        nemo-trilium = {
            url = "github:Trilium-Community/nemo-trilium";
            inputs.nixpkgs.follows = "nixpkgs";
        };
        nixos-plymouth = {
            url = "github:BeatLink/nixos-plymouth";
        };
        app-separators = {
            url = "github:/BeatLink/Plank-Separator";
            inputs.nixpkgs.follows = "nixpkgs";
        };
        # Deliberately does NOT follow nixpkgs: its CI builds this package against its own pin and pushes the result to claude-code.cachix.org, and
        # overriding nixpkgs changes the derivation and turns a substitution back into a local build of a 216MB closure on every bump.
        claude-code = {
            url = "github:sadjow/claude-code-nix";
        };
        calibre-web-nextgen = {
            url = "github:BeatLink/Calibre-Web-NextGen/feat/nix-services";
            inputs.nixpkgs.follows = "nixpkgs";
        };
        lnxlink = {
            url = "github:BeatLink/lnxlink";
            inputs.nixpkgs.follows = "nixpkgs";
        };
        nix-vscode-extensions = {
            url = "github:nix-community/nix-vscode-extensions";
            inputs.nixpkgs.follows = "nixpkgs";
        };
        vigil = {
            url = "github:BeatLink/Vigil";
            inputs.nixpkgs.follows = "nixpkgs";
        };
        context = {
            url = "github:BeatLink/Context";
            inputs.nixpkgs.follows = "nixpkgs";
        };
        nixtool = {
            url = "github:BeatLink/NixTool";
            inputs.nixpkgs.follows = "nixpkgs";
        };
        # Points at the fork's branch until josegonzalez/atuin-web#81 lands upstream
        atuin-web = {
            url = "github:BeatLink/atuin-web/nix-packaging";
            inputs.nixpkgs.follows = "nixpkgs";
        };
        nixos-hardware = {
            url = "github:NixOS/nixos-hardware";
            inputs.nixpkgs.follows = "nixpkgs";
        };
        # megi's PinePhone kernel. Deliberately does NOT follow nixpkgs: the
        # binary cache it publishes is built against its own pin, and overriding
        # nixpkgs changes the stdenv, changes the derivation, and turns a one
        # minute substitution back into a multi-hour aarch64 build.
        pinephone-kernel = {
            url = "github:BeatLink/PinePhoneKernel";
        };
        pinephone-charge = {
            url = "github:BeatLink/PinePhoneCharge";
            inputs.nixpkgs.follows = "nixpkgs";
        };

        waypipe-desktop = {
            url = "github:BeatLink/WaypipeDesktop";
            inputs.nixpkgs.follows = "nixpkgs";
        };
        # Points at the fork's branch until the Nix packaging lands in g0ldyy/comet
        comet = {
            url = "github:BeatLink/comet/nix-packaging";
            inputs.nixpkgs.follows = "nixpkgs";
        };
        battery-guardian = {
            url = "github:BeatLink/BatteryGuardian";
            inputs.nixpkgs.follows = "nixpkgs";
        };
    };
    outputs =
        inputs@{
            self,
            nixpkgs,
            nix-index-database,
            disko,
            impermanence,
            sops-nix,
            arion,
            home-manager,
            xdg-autostart,
            gmusicbrowser,
            halon,
            blockurl,
            mobile-nixos,
            app-separators,
            claude-code,
            calibre-web-nextgen,
            lnxlink,
            linux-sidebar,
            nemo-trilium,
            nixos-hardware,
            ...
        }:
        {
            nixosConfigurations = {
                Ragnarok = nixpkgs.lib.nixosSystem {
                    specialArgs = { inherit inputs; };
                    modules = [
                        { nixpkgs.hostPlatform = "aarch64-linux"; }
                        { home-manager.extraSpecialArgs = { inherit inputs; }; }
                        nix-index-database.nixosModules.nix-index
                        disko.nixosModules.disko
                        impermanence.nixosModules.impermanence
                        sops-nix.nixosModules.sops
                        home-manager.nixosModules.home-manager
                        ./nix/0-common
                        ./nix/1-backup-server
                    ];
                };
                Heimdall = nixpkgs.lib.nixosSystem {
                    specialArgs = { inherit inputs; };
                    modules = [
                        { nixpkgs.hostPlatform = "x86_64-linux"; }
                        { home-manager.extraSpecialArgs = { inherit inputs; }; }
                        nix-index-database.nixosModules.nix-index
                        disko.nixosModules.disko
                        impermanence.nixosModules.impermanence
                        sops-nix.nixosModules.sops
                        home-manager.nixosModules.home-manager
                        arion.nixosModules.arion
                        blockurl.nixosModules.blockurl
                        gmusicbrowser.nixosModules.default
                        calibre-web-nextgen.nixosModules.default
                        lnxlink.nixosModules.default
                        ./nix/0-common
                        ./nix/2-server
                    ];
                };
                Odin = nixpkgs.lib.nixosSystem {
                    specialArgs = { inherit inputs; };
                    modules = [
                        { nixpkgs.hostPlatform = "x86_64-linux"; }
                        {
                            home-manager = {
                                extraSpecialArgs = { inherit inputs; };
                                sharedModules = [
                                    xdg-autostart.homeManagerModules.xdg-autostart
                                    gmusicbrowser.homeManagerModules.gmusicbrowser
                                    lnxlink.homeModules.default
                                    linux-sidebar.homeManagerModules.default
                                    halon.homeManagerModules.default
                                    nemo-trilium.homeManagerModules.default
                                ];
                            };
                        }
                        nix-index-database.nixosModules.nix-index
                        disko.nixosModules.disko
                        impermanence.nixosModules.impermanence
                        sops-nix.nixosModules.sops
                        home-manager.nixosModules.home-manager
                        halon.nixosModules.default
                        nixos-hardware.nixosModules.lenovo-ideapad-15ach6
                        ./nix/0-common
                        ./nix/3-laptop
                    ];
                };
                Thor = nixpkgs.lib.nixosSystem {
                    specialArgs = { inherit inputs; };
                    modules = [
                        { nixpkgs.hostPlatform = "aarch64-linux"; }
                        { home-manager.extraSpecialArgs = { inherit inputs; }; }
                        nix-index-database.nixosModules.nix-index
                        disko.nixosModules.disko
                        impermanence.nixosModules.impermanence
                        sops-nix.nixosModules.sops
                        home-manager.nixosModules.home-manager
                        ./nix/0-common
                        ./nix/5-phone
                    ];
                };
            };
        };
}