InfinityBot/build.gradle at main · nextinfinity/InfinityBot · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
plugins {
    id "com.gradleup.shadow" version "9.6.1"
    id "io.freefair.lombok" version "9.7.0"
}

apply plugin: 'java'
version = providers.gradleProperty('appVersion').orElse('0.0.0-SNAPSHOT').get()
if (!(version.toString() ==~ /[0-9A-Za-z][0-9A-Za-z.+_-]*/)) {
    throw new GradleException('appVersion must contain only letters, digits, dots, plus signs, underscores, or hyphens, and start with a letter or digit.')
}

java {
    toolchain { languageVersion = JavaLanguageVersion.of(25) }
}

shadowJar {
    filesMatching('META-INF/*.kotlin_module') {
        duplicatesStrategy = DuplicatesStrategy.INCLUDE
    }
    mergeServiceFiles()
    filesMatching('META-INF/services/**') {
        duplicatesStrategy = DuplicatesStrategy.INCLUDE
    }
}

jar {
    manifest {
        attributes 'Main-Class': 'net.theinfinitymc.infinitybot.InfinityBot',
                'Implementation-Version': project.version.toString()
    }
}

repositories {
    mavenCentral()
    maven { url = "https://maven.lavalink.dev/releases" }
    maven {
        url = "https://maven.lavalink.dev/snapshots"
        content { includeGroup 'dev.lavalink.youtube' }
        mavenContent { snapshotsOnly() }
    }
}

configurations {
    mockitoAgent
}

tasks.named('test', Test) {
    useJUnitPlatform()
    jvmArgs "-javaagent:${configurations.mockitoAgent.singleFile}"
}

dependencies {
    testImplementation platform('org.junit:junit-bom:6.0.3')
    testImplementation 'org.junit.jupiter:junit-jupiter'
    testRuntimeOnly 'org.junit.platform:junit-platform-launcher'
    testImplementation 'org.mockito:mockito-core:5.23.0'
    mockitoAgent('org.mockito:mockito-core:5.23.0') { transitive = false }

    constraints {
        implementation('com.fasterxml.jackson.core:jackson-core:2.22.3') {
            because 'Fix GHSA-72hv-8253-57qq and GHSA-r7wm-3cxj-wff9 in transitive Jackson versions'
        }
        implementation('com.fasterxml.jackson.core:jackson-databind:2.22.3') {
            because 'Fix reported Jackson databind vulnerabilities, including GHSA-q4xh-88c3-wmh7 and GHSA-gx83-3vf8-gh7j'
        }
        implementation('commons-io:commons-io:2.22.0') {
            because 'Fix GHSA-78wr-2p64-hpwj in Lavaplayer/lava-common transitive dependencies'
        }
        implementation('org.jsoup:jsoup:1.23.2') {
            because 'Fix GHSA-pmhh-3w7g-xqp8 in Lavaplayer transitive dependencies'
        }
        implementation('org.mozilla:rhino:1.7.15.1') {
            because 'Fix GHSA-3w8q-xq97-5j7x without changing the Rhino release line'
        }
        implementation('org.mozilla:rhino-engine:1.7.15.1') {
            because 'Keep the YouTube/Lavaplayer script engine aligned with patched Rhino'
        }
    }

    implementation 'net.dv8tion:JDA:6.7.0'
    implementation 'club.minnced:jdave-api:0.1.8'
    runtimeOnly 'club.minnced:jdave-native-linux-x86-64:0.1.8'
    runtimeOnly 'club.minnced:jdave-native-linux-aarch64:0.1.8'
    runtimeOnly 'club.minnced:jdave-native-darwin:0.1.8'
    runtimeOnly 'club.minnced:jdave-native-win-x86-64:0.1.8'
    implementation 'dev.arbjerg:lavaplayer:2.2.7'
    implementation 'dev.lavalink.youtube:v2:2be8e542d3f6f178e048dca565892684c2e40177-SNAPSHOT'
    implementation 'org.reflections:reflections:0.10.2'

    runtimeOnly 'org.slf4j:slf4j-reload4j:2.0.20'
}